今天就跟大家分享一下WPS中大神级SUMPRODUCT函数，它是一个在计算方面非常强大的函数，灵活使用可以帮助我们快速解决许多日常工作中的问题。下面分享的6种用法可直接套用，实例图解带你玩转SUMPRODUCT函数！

SUMPRODUCT函数介绍

函数功能：SUMPRODUCT函数主要功能是返回相应的数据或区域乘积的和。

语法结构：=SUMPRODUCT（数组1,数组2,数组3, ...）。

语法解读：

1、数组1,数组2,数组3, ... 为 2 到 30 个数组，其相应元素需要进行相乘并求和。

2、数组参数必须具有相同的维数，否则，函数 SUMPRODUCT 将返回错误值 #VALUE!。

3、函数 SUMPRODUCT 将非数值型的数组元素作为 0 处理。

一、SUMPRODUCT函数基本用法，求乘积之和

如下图所示，这是一个商品单价和数量信息表，需要计算总价格。

在目标单元格中输入公式：

=SUMPRODUCT(B2:B7,C2:C7)

解读：

SUMPRODUCT函数的功能是返回相应的数据或区域乘积的和，公式=SUMPRODUCT(B2:B7,C2:C7)中，数据区域有B2:B7和C2:C7两个，这两个数据区域对应数据元素先乘积，后求和，得到最终的总价格。

二、SUMPRODUCT函数单条件计数

如下图所示，左侧是员工考核成绩表，然后根据性别统计女性员工人数

在目标单元格中输入公式：

=SUMPRODUCT(--(C2:C6="女"))

解读：

1、公式中的(C2:C6="女")就是把表格中的“性别”这列数据的每个元素跟“女”做判断，返回的结果是一个数组由逻辑值TRUE或者FALSE（备注：逻辑值TRUE可以看做1，逻辑值FALSE可以看做0）组成。

2、前面添加双减号“--”，其实就是一个减负运算，可以将文本数字串或逻辑值转换为数值，就是把逻辑值TRUE转成数值1，把逻辑值FALSE转成数值0。

因为SUMPRODUCT函数会将非数值型的数组元素作为0 处理，所以我们要先转换，装换后再求和。

3、当然除了添加双减号“--”外，乘以1（备注：逻辑值TRUE乘以1就是1，辑值FALSE乘以1是0）或者用函数N()装换成数值，公式如下

公式=SUMPRODUCT((C2:C6="女")*1)

或者

公式=SUMPRODUCT(N(C2:C6="女"))

三、SUMPRODUCT函数多条件计数

还是以下图为例，统计考核成绩大于90分的男性人数。

在目标单元格中输入公式：

=SUMPRODUCT((C2:C6="男")*(D2:D6>90))

解读：

多条计数其实跟单条件求和十分相似，只添加了一个条件，大家会发现这两个条件中间是使用的*（乘号）连接参数，这时因为两个条件返回都是非数值类型，必须要用*（乘号）。当然我们也可以想把两个条件结果根据单条件计数的方法先转化成数值类型，这样就可以使用,（逗号）连接参数了。

总之，是使用*（乘号）还是使用,（逗号）连接参数只要记住以下3点，然后直接套用公式就行：

①当求和区域中存在无法计算的内容，如文字信息、逻辑值，求和区域前必须使用乘号“*”；

②当求和区域不是一列而是一个多列矩形区域时，求和区域前必须使用乘号“*”；

③其它情况下一般乘号“*”与逗号“,”通用。

四、SUMPRODUCT函数单条件求和

如下图所示，对性别为“女”的员工销售业绩求和

在目标单元格中输入公式：

=SUMPRODUCT((D2:D6="女")*F2:F6)

解读：

公式中有二个数据区域分别是D2:D6="女"、F2:F6，当D2:D6性别区域内的值等于"女"时返回逻辑值TRUE（1），否则返回FALSE（0）。然后二个数据对应元素先乘积，再求和，从而计算得到女性员工销售业绩求和。

五、SUMPRODUCT函数多条件求和

如下图所示，对“业务部”考核成绩大于85的员工销售业绩求和

在目标单元格中输入公式：

=SUMPRODUCT((C2:C6="业务部")*(E2:E6>80)*F2:F6)

解读：

多条件求和同“单条件求和”类似，只是增加了一个判断条件而已。

六、SUMPRODUCT函数构建排名

如下图所示，对考核成绩进行排名

在目标单元格中输入公式：

=SUMPRODUCT(--($E$2:$E$6>E2))+1

解读：

1、构建排名其实就是一个单条件计数，对数据区域E2:E6锁定行和列，选中E2:E6后按一次F4键变成$E$2:$E$6，因为每个人的成绩统计时都要跟全部人比较。

2、对应为什么在后面加1，主要是因为因为条件统计大于本身的数量，不包含本身，所以加1就是自己的排名。