我是【桃大喵学习记】，欢迎大家关注哟~，每天为你分享职场办公软件使用技巧干货！

——首发于微信号：桃大喵学习记

日常工作中，我们经常需要对Excel数据进行多条件查找匹配。今天就跟大家分享5个Excel多条件查询公式，个个都能独当一面，真是职场好帮手，提高工作效率的利器。

如下图所示，左侧是员工考核成绩信息表，我们需要根据员工“名称”和“部门”查询“考核成绩”。

一、VLOOKUP函数公式

功能：在表格或数值数组的首列查找指定的数值，并由此返回表格或数组当前行中指定列处的数值。

语法：=VLOOKUP（查找值，数据表（查找区域），列序数，[匹配条件]）

VLOOKUP应该是大家非常熟悉的函数了，如果想用这个函数来进行多条件查询，需要借助IF来构建二维数组。

推荐指数：⭐⭐

操作方法：

在目标单元格输入公式：

=VLOOKUP(F3&G3,IF({1,0},B:B&C:C,D:D),2,0)

然后通过点击回车即可。

解读：

①上面公式的关键是在于使用if({1,0})构建出一个新的数据区域。

②函数参数说明

第1参数：F3&G3是两个查找值连接起来作为查找值；

第2参数：IF({1,0},B:B&C:C,D:D)，意思就是当它为1时，返回B:B&C:C的值，它为0时，返回D列的值，得到了一个虚拟数组作为查找区域，B:B&C:C列在前面，D列在后面；

第3参数：2表示返回上面的虚拟数组第二列即D列数据；

第4参数：设置为0表示精确匹配。

二、INDEX+MTACH万能查询公式

功能：INDEX+MATCH函数组合做为一个万能查找组合，需要先使用MATCH来查询结果所在位置，然后再使用INDEX来返回对应的数据结果，有时能够帮助我们快速解决问题。

语法：=INDEX(返回结果列,MATCH(查找值，查找区域，0))

推荐指数：⭐⭐⭐

操作方法：

在目标单元格中输入公式：

=INDEX(D3:D9,MATCH(F3&G3,B3:B9&C3:C9,0))

然后点击回车即可

解读：

上面公式首先通过MATCH(F3&G3,B3:B9&C3:C9,0)获取查询值所在行号，然后再通过INDEX函数去结果列里面，找对应这个行的值。

三、FILTER函数公式

功能：FILTER是基于定义的条件筛选一系列数据的函数，它由数组，包括，空值三个参数所构成。

语法：使用语法=FILTER(数组，包括，空值)

第1个参数【数组】：就是筛选区域

第2个参数【包括】：就是筛选列=筛选条件

第3个参数【空值】：可以忽略，这个参数就是如果出现错误值可以设置返回信息

推荐指数：⭐⭐⭐⭐⭐

操作方法：

在目标单元格输入公式：

=FILTER(D3:D9,(B3:B9=F3)*(C3:C9=G3),"无数据")

然后点击回车键获取数据。

解读：

①公式中第1参数：多条件筛选使用的是(B3:B9=F3)*(C3:C9=G3)，有几个条件就用括号（）和星号*连接，星号*的意思就是AND且的意义，会筛选出同时满足这几个条件的查询结果。如果查询的空值就返回第2参数："无数据"。

②D3:D9是筛选区域，符合条件即返回数据。

干货分享：使用FILTER进行多条件查询窍门在第2个参数

还是以上面FILTER函数进阶用法：多条件查询为例

1、如果需要多个条件同时满足，就用*把多个条件连接

条件1*条件2*条件N

(B3:B9=F3)*(C3:C9=G3)

2、如果需要多个条件满足任意一个，就用+把多个条件连接

条件1+条件2+条件N

(B3:B9=F3)+(C3:C9=G3)

四、XLOOKUP函数公式

功能：XLOOKUP函数是一个查找函数，在某个范围或数组中搜索匹配项，并通过第二个范围或数组返回相应的项，默认情况下使用精准匹配。

语法：=XLOOKUP(查找值,查找数组,返回数组,未找到值,匹配模式,搜索模式)。

XLOOKUP函数参数虽然比较多，但是第四、第五、第六参数都是可以省略的，我们在平时使用这个函数时一般只需设置前三个函数即可。

推荐指数：⭐⭐⭐⭐⭐

操作方法：

在目标单元格中输入公式：

=XLOOKUP(F3&G3,B3:B9&C3:C9,D3:D9)

然后点击回车键获取数据。

解读：

①第1参数：想要查找值是F3和G3，所以中间用“&”符号链接即可，查找值就是F3&G3，也就是按右侧查询表格中的“姓名+部门”这两个条件。

②第2参数：要查询的数据区域，同样是左侧表格的“姓名”和“部门”两列，所以中间也是用“&”符号链接，即B3:B9&C3:C9，也就是左边数据源表格中的“姓名+部门”这两列数据。

③第3参数：要返回的数据区域就是员工的考核成绩这一列数据。

五、DGET函数公式

功能：从数据库提取符合指定条件的单个记录。这个函数是一个数据库函数，它能根据表头字段的名称来精准匹配数据，设置参数时，记得要包含这些表头字段名称。

语法：=DGET(带表头的查询表,返回结果的表头名称,查找条件)

推荐指数：⭐⭐⭐⭐⭐

操作方法：

在目标单元格中输入公式：

=DGET(A2:D9,D2,F2:G3)

然后点击回车键获取数据。

解读：

使用这个函数公式时，选择查询表格时必须包含表格表头信息，设置参数时，必须要包含查询表中的表头字段名称。

第1参数：A2:D9就是带着表头信息的要查询的表格数据区域；

第2参数：D2就是要返回结果列表头名称“考核成绩”；

第3参数：F2:G3就是查询条件，这个查询结果表表头名称必须跟左侧查询表格中的表头名称一致。

以上就是【桃大喵学习记】今天的干货分享~觉得内容对你有所帮助，别忘了动动手指点个赞哦~。大家有什么问题欢迎关注留言，期待与你的每一次互动，让我们共同成长！